Curvas planas¶

En esta sesión vamos a utilizar varios métodos de representación de curvas en el plano:

en paramétricas;

en coordenadas polares;

por una ecuación implícita.

Ecuaciones paramétricas¶

Pensaremos en una curva plana como la imagen por una función continua $\gamma: I\longrightarrow \mathbb R^2$ , con I un intervalo de números reales. Si tomamos $t$ como variable independiente ( $t\in\mathbb R$ ), describiremos la imagen como el conjunto de puntos

$\Gamma&=\gamma(I)=\big\{(x(t),y(t))\,:\, t\in I\big\}$

o simplemente

$\Gamma &: \big(\,x(t)\,,\,y(t)\,\big)$

Cuando el dominio de valores para el parámetro $t$ es un intervalo, digamos $[a,b]$ , la curva tiene como extremos los puntos: $(x(a),y(a))$ y $(x(b), y(b))$ .

Ejemplos¶

La curva $\Gamma: (t,t)$ , para $t\in (0,1)$ , es el segmento de recta que une los puntos $(0,0)$ y $(1,1)$ . En general, si $P$ y $Q$ son dos puntos, un segmento rectilíneo que une $P$ con $Q$ es: $\Gamma: (1-t)\cdot P+t\cdot Q$ , considerando $t\in(0,1)$ .

Antes de continuar, vamos a utilizar Sage para ‘ dibujar ‘ este ejemplo. Necesitamos que nuestro código sepa interpretar la expresión $(1-t)\cdot P+t\cdot Q$ como lo haríamos nosotros, a saber: si $P=(x_0,y_0)$ y $Q=(x_1,y_1)$ , el resultado queda:

$\begin{array}{rl} (1-t)\cdot(x_0,y_0)+t\cdot(x_1,y_1)&=\big((1-t)x_0,(1-t)y_0\big)+\big(tx_1,ty_1\big)\\ &=\big(x_0+t(x_1-x_0)\,,\,y_0+t(y_1-y_0)\big) \end{array}$

Esta manipulación (afín), no es más que tratar a los puntos $P$ y $Q$ como vectores (los vectores $OP$ y $OQ$ , cuando se ha fijado un punto como origen del plano afín). En el siguiente código se consigue este propósito. Utilizamos la función parametric_plot de Sage (leer la ayuda antes de seguir). Obsérvese en qué manera se explicita el intervalo para la variable $t$ .

sage: parametric_plot?
<html>...</html>

sage: # Segmento rectilíneo entre dos puntos P y Q
sage: var('t')
sage: P=vector((1,-1))
sage: Q=vector((2,2))
sage: #Observación
sage: show((1-t)*P+t*Q)

$\left(t + 1,3 \, t - 1\right)$

sage: parametric_plot((1-t)*P+t*Q, (t, 0, 1))

sage: parametric_plot( (t + 1, 3*t - 1) , (t, 0, 1))

Más ejemplos¶

Si tenemos una función (continua) real de variable real, $f:\mathbb R\longrightarrow\mathbb R$ , la gráfica es una curva en el plano, $\{(x,f(x))\,:\,x\in\mathbb R\}$ , que podemos presentar paramétricamente (tomando $x=t$ ). Estos son casos particulares de curvas, en las que no hay más de un punto en cada vertical (¿por qué?).

Una parábola: $(t,t^2)$

Una exponencial: $(t,e^t)$

Curvas trigonométricas: $(t,\sin(t))$ , $(t,\cos(t))$ , $\dots$

Funciones racionales: $\Big(t,\frac{1-t}{t^2+3t}\Big)$ , $t\neq-3,0$ . En los puntos en que una función tal no es continua, la gráfica no es fiel (comprobarlo).

Polinomios, ...

sage: p = parametric_plot((t,(1-t)/(t^2+3*t)), (t,-5,2))
sage: p.show(ymin=-5, ymax=5)

Y los más interesantes¶

La mayoría del lenguaje de curvas parametrizadas viene del estudio del movimiento de una partícula. En esos casos, el parámetro de la curva suele ser el tiempo (¡qué buena elección de letra $t$ !), y cada punto de la curva marca la posición de la partícula en cada momento. Así el segmento rectilíneo entre dos puntos $P$ y $Q$ descrito por $\Gamma: (1-t)\cdot P+t\cdot Q,\,t\in[0,1]$ sería la trayectoria descrita por una partícula que viaja en línea recta, partiendo de $P$ y llegando a $Q$ en una unidad de tiempo ( $t\in[0,1]$ ).

Este enfoque nos surte de una cantidad tremenda de ejemplos, históricamente estudiados por grandes físicos y matemáticos, de los que a continuación exponemos una brevísima lista (para ver más visitar, por ejemplo: mathcurve.com , epsilones.com ):

Circunferencia (centrada en el origen y de radio $\rho$ ): $\big(\rho\cos t,\rho\sin t\big)\,,\,t\in[0,2\pi)$

Bruja de Agnesi: $\big(2at,2a/(1+t^2)\big)$ ( $a$ es el radio de la circunferencia base —ver construcción más abajo)

Astroide: $(a\cos^3(t), a\sin^3(t))$ , $t\in[0,2\pi)$

El folium de Descartes: $\Big(\frac{3at}{1+t^3},\frac{3at^2}{1+t^3}\Big)$ , $t\in(-1,1)$ . Nota: el cambio $t$ por $1/t$ , cambia $x$ e $y$ .

???: $\big(\sin(3t), \cos(4t)+4\cos t\big),\,t\in[0,2\pi)$

sage: # Dibujamos el folium de Descartes pegando dos ramas simétricas respecto al eje (y=x).
sage: rama1=parametric_plot((t/(1+t^3),t^2/(1+t^3)), (t,-.5,1))
sage: rama2=parametric_plot((t^2/(1+t^3),t/(1+t^3)), (t,-.5,1), color=(0,1,0))
sage: show(rama1+rama2, aspect_ratio=1)

sage: #Cúbica (o bruja) de Agnesi
sage: var('t theta x y')
sage: a = 1
sage: bruja = parametric_plot((2*a*t,2*a/(t^2+1)), (t, -2, 2))
sage: #circle dibuja una circunferencia de centro y radio dados
sage: circ_bruja = circle((0,a),a)
sage: ambas = bruja + circ_bruja
sage: show(ambas, aspect_ratio=1)

Construcción de la curva de Agnesi¶

Se consideran dos puntos diametralmente opuestos en una circunferencia, $O$ y $N$ , y la tangente, $\ell$ , a la circunferencia por uno de ellos, digamos que por $N$ . Desde el otro, hacemos la siguiente construcción

para cada punto de la circunferencia, $X$ , tomamos el punto de corte de la recta $OX$ con la recta $\ell$ : $X'=OX\cap\ell$ ;

completamos un triángulo rectángulo con $X$ , $X'$ y un tercer punto, $P(X)$ , en la recta, $\ell(X)$ , paralela a $\ell$ por el punto $X$ : el ángulo recto sobre el vértice nuevo, $P(X)$ .

La curva de Agnesi es la descrita por los puntos $P(X)$ .

sage: var('a t s x y')
(a, t, s, x, y)

sage: solve((2*a*t*s)^2+(2*a*s-a)^2-a^2,s)
[s == (1/(t^2 + 1)), s == 0]

Coordenadas polares¶

Una manera alternativa de indicar la posición de cada punto es mediante sus coordenadas polares $(\rho,\theta)$ , siendo $\rho$ la distancia del punto al origen, y $\theta$ el ángulo que forma el vector que une el origen con el punto y el semieje horizontal positivo, es decir: si $P=(x,y)$

$\rho=\sqrt{x^2+y^2}\,,\qquad \theta=\arctan\frac yx\,.$

Obsérvese que la función $\arctan$ nos devuelve el valor correcto del ángulo salvo, quizás, un error de $\pi$ (pues $\tan(\alpha)=\tan(\alpha\pm\pi)$ ). El cambio inverso, de polares a cartesianas, es más preciso:

$x=\rho\cos\theta\,,\qquad y=\rho\sin\theta\,.$

Es claro que $\rho\ge0$ así como que basta tomar ángulos $\theta$ en el intervalo $[0,2\pi)$ , por ejemplo.

Para dar la ecuación en polares de una curva, se suele expresar el radio como una función del ángulo, pero se representa en el plano cartesiano. Así, si dibujamos la curva $\Gamma: \rho=cos^2(\theta)\,,\,\theta\in[0,2\pi)$ , estaremos dibujando los puntos del plano $(x,y)$ , con $x=\rho\cos\theta=\cos^2(\theta)\cdot\cos\theta=\cos^3\theta$ , e $y=\cos^2\theta\cdot\sin\theta$ , variando $\theta$ , en este caso, entre $0$ y $2\pi$ .

La función de Sage que utilizamos en este caso es polar_plot (revisar su ayuda en línea), que es equivalente a utilizar el valor polar=True en un plot() .

sage: polar_plot?
<html>...</html>

sage: var('theta')
sage: polar_plot(cos(theta)^2, (theta,0,2*pi))

Ejemplos¶

Recta de ecuación $Ax+By=1$ (no pasa por el origen). Si $p=1/\sqrt{A^2+B^2}$ y $\alpha$ es el ángulo definido por $\cos\alpha=Ap$ , $\sin\alpha=Bp$ , entonces: $\rho=\dfrac{p}{\cos(\theta-\alpha)}$ es su ecuación en polares.

Recta que pasa por el origen: en este caso la descripción es más sencilla, pues todos los puntos de la recta (al unirse al origen) forman un ángulo constante con el eje de abcisas. Así, si dicho ángulo es $\alpha_0$ la ecuación es $\theta=\alpha_0$ . Ahora bien, no podemos indicarle a Sage cómo dibujarlas utilizando polar_plot() (ocurre como en la representación de rectas verticales, $x=\mathrm{constante}$ , en coordenadas cartesianas).

Como vemos, las rectas no son muy amigables para representar en polares. Sigamos con ejemplos más enriquecedores.

Circunferencia (con centro el origen): $\rho=\mathrm{constante}$ , $\theta\in[0,2\pi)$ . Y si el ángulo lo variamos menos, conseguimos cualquier arco de circunferencia.

Circunferencia que pasa por el origen: $\rho=A\cos\theta+B\sin\theta$ , $\theta\in[0,2\pi)$ . Nota: el centro es el punto de coordenadas cartesianas $(A/2,B/2)$ .

Cónica con un foco en el origen: la ecuación de la cónica, dado un foco, necesita conocer la recta directriz y la excentricidad $e$ . Si tal recta tiene ecuación cartesiana $x\cos\alpha+y\sin\alpha=q$ , la cónica es el lugar de puntos $M$ tales que $\Vert OM\Vert=e\Vert MH\Vert$ , siendo $H$ la proyección ortogonal de $M$ sobre la directriz. En tal caso, la ecuación polar de la cónica queda:

$\rho=\frac{p}{1+e\cos(\theta-\alpha)}\,,\qquad p=eq\,.$

La recta $\Delta$ de ecuación $\theta=\alpha$ es eje de simetría. Cuando $e=1$ la cónica es una parábola, $\Delta$ su eje de simetría y $(p/2,\alpha)$ su vértice. Cuando $e\neq1$ la cónica es una cónica con centro, $\Delta$ el eje focal y sus vértices se calculan sustituyendo $\theta$ por $\alpha$ y $\alpha+\pi$ .

Últimos ejemplos¶

Por último una lista de curvas famosas con sus ecuaciones polares:

Rosas: $\rho=a\cos(n\theta)$ , $\theta\in[0,2\pi)$ . Ejercicio : averiguar el número de pétalos para cada valor natural de $n$ . Nota: $n$ puede ser cualquier real positivo.

La cardiode: $\rho=a(1+\cos\theta)$ , $\theta\in[0,2\pi)$ .

La cisoide: $\rho=a\frac{\sin^2\theta}{\cos\theta}$ , $\theta\in[0,2\pi)$ .

La estrofoide: $\rho=a\frac{\cos(2\theta)}{\cos\theta}$ , $\theta\in[0,2\pi)$ .

La lemniscata de Bernoulli: $\rho^2=a^2\cos(2\theta)$ , $\theta\in[0,2\pi)$ .

Espirales:

Espiral de Arquímedes: $\rho=a\theta$ , $\theta\in[0,+\infty)$ .

Espiral hiperbólica: $\rho=a/\theta$ , $\theta\in[0,+\infty)$ .

Espiral logarítmica: $\rho=ae^{m\theta}$ , $\theta\in[0,+\infty)$ .

sage: rosas=polar_plot(2*cos(6*theta), (theta,0,2*pi))
sage: show(rosas, aspect_ratio=1)

var('theta')
a,b=0,2*pi
n=48 ## puntos a mostrar
h=(b-a)/n ## equidistantes en el intervalo original
ro(theta)=2*cos(6*theta)
xx(theta)=ro(theta)*cos(theta) ## x-Cartesiana
yy(theta)=ro(theta)*sin(theta) ## y-Cartesiana
rosa=polar_plot(ro(theta), (theta,a,b), figsize=3, axes=false)
camino=[] ## inicio de la lista de fotogramas
for k in srange(a,b,h):
    camino.append(rosa+point((xx(k),yy(k)), size=25))
a=animate(camino, figsize=(6,6))
a.show()

Coordenadas cartesianas¶

Aunque no han dejado de usarse, hasta aquí no hemos pedido a Sage que represente una curva cuyas ‘ecuaciones’ le vienen dadas en función de sus coordenadas cartesianas. Lo hasta ahora habitual es encontrarnos con que la coordenada $y$ es una función de la coordenada $x$ : $y=f(x)$ . Las herramientas del cálculo diferencial nos ayudan a esbozar este tipo de gráficas. En este apartado vamos a adoptar un punto de vista más general, dando una ecuación de la curva en la que ambas variables puedan aparecer en la expresión sin que sea necesario despejar una en función de la otra.

Ecuaciones implícitas¶

La ecuación $Ax+By=C$ , con $A,\,B$ y $C$ números reales, nos sirve para describir todos los puntos del plano cuyas coordenadas, $(x,y)$ , la verifican. Es fácil comprobar que todos estos puntos quedan alineados, es decir describen una línea recta. De la ecuación dada decimos que es su ecuación cartesiana o implícita , y basta, para calcularla con dar dos puntos de la recta, o un punto y una dirección (vector director).

Una ecuación implícita de la recta que pasa por los puntos de coordenadas $(x_0,y_0)$ , $(x_1,y_1)$ surge de desarrollar la siguiente igualdad:

$\mathrm{det}\Bigg(\begin{array}{cc} x-x_0 & x_1-x_0\\ y -y_0 & y_1-y_0\end{array}\Bigg)=0\,.$

Si conocemos que la recta pasa por el punto de coordenadas $(x_0,y_0)$ y la dirección de la recta es la del vector $\mathbf v=(v_x,v_y)$ , una ecuación implícita la obtenemos al desarrollar:

$\mathrm{det}\Bigg(\begin{array}{cc} x-x_0 & v_x\\ y-y_0 & v_y\end{array}\Bigg)=0\,.$

Con ambos puntos de vista, los coeficientes $A$ y $B$ de la ecuación resultante, $Ax+By=C$ , determinan un vector $\mathbf n=(A,B)$ (vector normal de la recta) que es perpendicular a la recta, en particular: a $(x_1-x_0,y_1-y_0)$ en la primera descripción; a $\mathbf v$ , en la segunda.

Ejercicio¶

Encuentra la ecuación de la recta que pasa por dos puntos usando álgebra lineal.

Más ecuaciones implícitas¶

Por cinco puntos distintos del plano pasa una única cónica . Este sencillo principio es una manera escueta de afirmar que con fijar cinco puntos distintos (en posición general), somos capaces de encontrar (determinar los coeficientes de) una ecuación implícita de la forma $ax^2+by^2+cxy+dx+ey+f=0$ , y que cualquier otra es el resultado de multiplicar todos los coeficientes por un factor no nulo. Aunque no entraremos en el concepto general de “puntos en posición general”, basta decir que en este caso quiere decir que los puntos son distintos y que no hay tres que estén alineados.

Este problema, dadas las coordenadas de los cinco puntos, se puede resolver con cálculo matricial. Si $P_i=(x_i,y_i)$ , para $i=1,\dots,5$ , son cinco puntos distintos, la ecuación buscada, de la forma $ax^2+by^2+cxy+dx+ey+f=0$ , es verificada por todos ellos, y así se plantean las cinco ecuaciones

$\begin{array}{rcl} x_1^2a+y_1^2b+x_1y_1c+x_1d+y_1e+1\cdot f&=0\\ x_2^2a+y_2^2b+x_2y_2c+x_2d+y_2e+1\cdot f&=0\\ x_3^2a+y_3^2b+x_3y_3c+x_3d+y_3e+1\cdot f&=0\\ x_4^2a+y_4^2b+x_4y_4c+x_4d+y_4e+1\cdot f&=0\\ x_5^2a+y_5^2b+x_5y_5c+x_5d+y_5e+1\cdot f&=0\\ \end{array}$

que son lineales en sus incógnitas (los coeficientes $a$ , $b$ , $\dots$ , $f$ ). Este es un sistema lineal compatible, y si los puntos están en posición general su matriz de coeficientes es de rango $5$ . Si $(a_0,b_0,c_0,d_0,e_0,f_0)$ es una solución (no trivial), cualquier otra es de la forma $\lambda\cdot(a_0,b_0,c_0,d_0,e_0,f_0)$ . Pero es obvio que todas estas soluciones nos dan ecuaciones para una misma curva (¿por qué?).

Encuentra la cónica que pasa por cinco puntos en posición general:

$ax^2+by^2+cxy+dx+ey+f=0$

sage: puntos = [(0,0),(0,1),(1,3),(2,1),(1,0)]

sage: var('x y')
sage: coefs = matrix(QQ,5,6)
sage: for j in range(5):
...       x0, y0 = puntos[j]
...       coefs[j,0] = x0^2    #Primera columna (coef. de a)
...       coefs[j,1] = y0^2    #Segunda columna (coef. de b)
...       coefs[j,2] = x0*y0   #Tercera columna (coef. de c)
...       coefs[j,3] = x0      #Cuarta columna (coef. de d)
...       coefs[j,4] = y0      #Quinta columna (coef. de e)
...       coefs[j,5] = 1       #Sexta columna (coef. de f)

sage: show(coefs)

$\left(\begin{array}{rrrrrr} 0 & 0 & 0 & 0 & 0 & 1 \\ 0 & 1 & 0 & 0 & 1 & 1 \\ 1 & 9 & 3 & 1 & 3 & 1 \\ 4 & 1 & 2 & 2 & 1 & 1 \\ 1 & 0 & 0 & 1 & 0 & 1 \end{array}\right)$

sage: sol = coefs.solve_right(vector([0,0,0,0,0]))
sage: show(sol)
sage: coefs.right_kernel().basis()[0]
(1, 1/2, -1, -1, -1/2, 0)

$\left(0,0,0,0,0,0\right)$

sage: vk = coefs.right_kernel().basis()[0]
sage: a,b,c,d,e,f = vk
sage: curva = a*x^2 + b*y^2 + c*x*y + d*x + e*y + f
sage: show(curva)

$x^{2} - x y + \frac{1}{2} \, y^{2} - x - \frac{1}{2} \, y$

sage: implicit_plot(curva,(x,-1,4),(y,-1,5))+point2d(puntos,color=(1,0,0),pointsize=30)

Ejercicio¶

Encuentra 5 puntos tal que la cónica que pasa por ellos sea una hipérbola.

Un ejemplo de haz de curvas¶

Si fijamos 4 puntos del plano en posición general, encontramos muchas cónicas que pasan por todos los puntos. En este caso, los coeficientes de la ecuación de la cónica que pasa por los 4 puntos deben satisfacer 4 ecuaciones:

$\begin{array}{rcl} x_1^2a+y_1^2b+x_1y_1c+x_1d+y_1e+1\cdot f&=0\\ x_2^2a+y_2^2b+x_2y_2c+x_2d+y_2e+1\cdot f&=0\\ x_3^2a+y_3^2b+x_3y_3c+x_3d+y_3e+1\cdot f&=0\\ x_4^2a+y_4^2b+x_4y_4c+x_4d+y_4e+1\cdot f&=0\\ \end{array}$

sage: puntos = [(0,0),(0,1),(1,0),(2,2)]

sage: var('x y')
sage: coefs = matrix(QQ,4,6)
sage: for j in range(4):
...       x0, y0 = puntos[j]
...       coefs[j,0] = x0^2
...       coefs[j,1] = y0^2
...       coefs[j,2] = x0*y0
...       coefs[j,3] = x0
...       coefs[j,4] = y0
...       coefs[j,5] = 1

sage: show(coefs)

$\left(\begin{array}{rrrrrr} 0 & 0 & 0 & 0 & 0 & 1 \\ 0 & 1 & 0 & 0 & 1 & 1 \\ 1 & 0 & 0 & 1 & 0 & 1 \\ 4 & 4 & 4 & 2 & 2 & 1 \end{array}\right)$

sage: K = coefs.right_kernel()
sage: v1 = K.basis()[0]
sage: v2 = K.basis()[1]
sage: show(K.basis())

$\left[\left(1,0,-\frac{1}{2},-1,0,0\right), \left(0,1,-\frac{1}{2},0,-1,0\right)\right]$

Cualquier vector no nulo de K da lugar a una cónica que pasa por los 4 puntos. No todas son equivalentes, aunque por supuesto dos vectores proporcionales dan lugar a la misma curva. Al conjunto de cónicas que pasa por los cuatro puntos lo llamamos el haz de cónicas por los 4 puntos.

sage: c1 = 1
sage: c2 = -3
sage: a,b,c,d,e,f = c1*v1 + c2*v2
sage: curva = a*x^2 + b*y^2 + c*x*y + d*x + e*y + f
sage: grafica = point2d(puntos,color=(1,0,0),pointsize=30) + implicit_plot(curva,(x,-1,4),(y,-1,4))
sage: grafica.show()

Ejercicio¶

Dibuja varias cónicas del haz en la misma gráfica .

Curvas planas¶

Ecuaciones paramétricas¶

Ejemplos¶

Más ejemplos¶

Y los más interesantes¶

Construcción de la curva de Agnesi¶

Coordenadas polares¶

Ejemplos¶

Últimos ejemplos¶

Coordenadas cartesianas¶

Ecuaciones implícitas¶

Ejercicio¶

Más ecuaciones implícitas¶

Ejercicio¶

Un ejemplo de haz de curvas¶

Ejercicio¶

Contenidos

Tema anterior

Próximo tema

Esta página

Navegación

Curvas planas¶

Ecuaciones paramétricas¶

Ejemplos¶

Más ejemplos¶

Y los más interesantes¶

Construcción de la curva de Agnesi¶

Coordenadas polares¶

Ejemplos¶

Últimos ejemplos¶

Coordenadas cartesianas¶

Ecuaciones implícitas¶

Ejercicio¶

Más ecuaciones implícitas¶

Ejercicio¶

Un ejemplo de haz de curvas¶

Ejercicio¶

Contenidos

Tema anterior

Próximo tema

Esta página

Búsqueda rápida

Navegación